Revista MSDN Magazine Edi��o 08 - As Novidades do Visual FoxPro 9.0 Beta

Clique aqui para ler todos os artigos desta ediç�o

As Novidades do Visual FoxPro 9.0 Beta

O Visual FoxPro sempre foi conhecido como uma ferramenta que procura atender �s necessidades mais urgentes dos desenvolvedores. A cada nova vers�o, s�o incorporados recursos valiosos ao produto, geralmente resultantes do �feedback� da comunidade de usu�rios. O Visual FoxPro 9.0, a nova vers�o da ferramenta cujo lançamento est� previsto para o �ltimo trimestre de 2004, continua honrando essa tradiç�o e trar� recursos que tornar�o os desenvolvedores ainda mais produtivos e capazes de entregar soluç�es mais poderosas e flex�veis.

Muitas s�o as novidades desta nova vers�o, e v�rias delas j� poder�o ser testadas na vers�o Beta, a ser disponibilizada publicamente na primeira metade de Junho/2004. Sendo assim, tentarei melhorar a leitura deste artigo organizando-o em t�picos correspondentes a cada principal �rea de destaque do Visual FoxPro 9.0 Beta. Falarei das melhorias no acesso e manipulaç�o de dados; Ambiente Integrado de Desenvolvimento (IDE); Interface de Usu�rio e Relat�rios. Al�m disso, tamb�m procurarei citar quest�es importantes de interoperabilidade, como integraç�o com o .NET e manipulaç�o de documentos XML.

Acesso e Manipulaç�o de Dados

Um dos grandes diferenciais do VFP sempre foi o suporte nativo � linguagem SQL. Esse suporte foi bastante melhorado no VFP 9.0 Beta atrav�s da adiç�o de mais recursos do padr�o ANSI-92. Alguns deles s�o mostrados na Listagem 1 (todos os exemplos s�o baseados no database Northwind, distribu�do com o VFP).

Listagem 1. Seleç�o do total de pedidos por cliente usando subqueries nas cl�usulas FROM e SELECT.


        *--
        *-- Total dos pedidos por cliente (usando sub-query na cl�usula FROM)
        *--
        SELECT Cust.CustomerID, Cust.CompanyName, Soma.SomaPedidos ;
        FROM Customers Cust LEFT JOIN ;
        ( ;
        SELECT CustomerID, ;
        SUM(I.Quantity * I.UnitPrice) as SomaPedidos ;
        FROM Orders P INNER JOIN OrderDetails I ;
        ON P.OrderId = I.OrderId ;
        GROUP BY CustomerID ;
        ) as Soma ;
        ON Soma.CustomerID = Cust.CustomerID
        *--
        *-- Total dos pedidos por cliente (usando sub-query na cl�usula SELECT)
        *--
        SELECT Cust.CustomerID, Cust.CompanyName, ;
        ( ;
        SELECT SUM(I.Quantity * I.UnitPrice);
        FROM Orders P INNER JOIN OrderDetails I ;
        ON P.OrderId = I.OrderId ;
        WHERE P.CustomerID = Cust.CustomerID ;
        ) as SomaPedidos ;
        FROM Customers Cust

As consultas da Listagem 1 realizam o mesmo trabalho: obter o total dos pedidos por cliente. Entretanto, elas ilustram duas novas possibilidades do comando SELECT-SQL no VFP 9.0 Beta: a utilizaç�o de �subqueries� (consultas aninhadas) nas cl�usulas SELECT e FROM. Outras melhorias incluem:

M�ltiplas subqueries aninhadas;
Subqueries na c�usula WHERE, no formato: [ ALL | ANY | SOME] (Subquery);
Subqueries na cl�usula SET em comandos UPDATE-SQL;
UNION em construç�es INSERT INTO ... SELECT ...;

Al�m das melhorias funcionais na sintaxe do SQL, o VFP 9.0 Beta conta ainda com as seguintes novidades em relaç�o ao acesso a dados:

Novos tipos de dados: VARCHAR, VARBINARY e BLOB para o armazenamento de valores em colunas de tamanho vari�vel e tipos bin�rios puros;
Nova funç�o CAST() para convers�o din�mica de dados;
Novo �ndice bin�rio para fontes de dados nativas, que pode ser aplicado para colunas bi valoradas sem o efeito colateral causado nas vers�es anteriores do VFP (onde esse procedimento prejudicava a performance em cen�rios de acesso remoto;
Possibilidade de retornar um cursor a partir de stored procedures em um Database Container (DBC) que sejam acessadas atrav�s do novo OLEDB Provider do VFP 9.0 Beta;
Novas funç�es MAKETRANSACTABLE() e ISTRANSACTABLE(), que permitem habilitar e controlar transaç�es em tabelas DBF livres, ou seja, sem necessidade de haver um DBC.

XML e Integraç�o com o .NET

A vers�o anterior do Visual FoxPro, o VFP 8.0, foi sem d�vida respons�vel por um grande avanço na �rea de interoperabilidade e integraç�o com o .NET Framework. O VFP 9.0 Beta traz v�rias melhorias em algumas das classes que desempenham um importante papel nesta integraç�o: XMLAdapter, XMLTable e XMLColumn.

O suporte � geraç�o de documentos XML hier�rquicos, ou seja, documentos cujos dados relacionam-se entre si e cuja relaç�o � determinada pelo aninhamento dos elementos dentro do mesmo (por exemplo, o relacionamento pai/filho) foi bastante melhorado nesta vers�o. Agora � poss�vel determinar a forma como os diversos elementos do documento XML dever�o estar aninhados. Isso proporciona enorme flexibilidade ao gerar documentos XML a partir de fontes de dados nativas e export�-los para outras aplicaç�es, ou ainda, para importar documentos com vocabul�rios diversos a fim de transform�-los mais facilmente em cursores nativos para manipulaç�o no ambiente do VFPM.

O c�digo da Listagem 2 apresenta um pequeno exemplo que ilustra a geraç�o de um documento onde os itens pertencentes aos dados dos pedidos de venda estar�o aninhados dentro dos elementos dos clientes correspondentes. A Figura 1 mostra o documento XML resultante da execuç�o do c�digo (neste, caso o esquema XSD foi omitido por raz�es de limitaç�o de espaço).

Listagem 2. Exemplo de geraç�o de um documento XML hier�rquico que relaciona tr�s tabelas.


        LOCAL loXA as XMLAdapter
        LOCAL loBrowser as InternetExplorer.Application
        LOCAL loExcecao as Exception
        LOCAL lcCliente as String
        TRY
        CLOSE DATABASES ALL
        *-- Abre as tabelas Orders e OrderDetails do database Northwind
        OPEN DATABASE _Samples + "Northwind\Northwind"
        *-- Vamos selecionar os dados do cliente CENTC
        lcCliente = "CENTC"
        *-- Seleciona o registro do cliente 'CENTC'
        SELECT CustomerID, CompanyName ;
        from Customers ;
        WHERE CustomerID = m.lcCliente INTO CURSOR Clientes READWRITE
        *-- Seleciona os pedidos do cliente
        SELECT OrderId, CustomerID, OrderDate ;
        FROM Orders ;
        WHERE CustomerID = m.lcCliente INTO CURSOR Pedidos READWRITE
        *-- Seleciona os itens dos pedidos
        SELECT I.OrderID, I.ProductId, I.UnitPrice, I.Quantity ;
        FROM OrderDetails I LEFT JOIN Orders P;
        ON I.OrderID = P.OrderID ;
        WHERE P.CustomerID = m.lcCliente INTO CURSOR Itens READWRITE
        *--
        *-- Estabelece um relacionamento entre os cursores.
        *-- Isto ser� importante mais tarde quando formos serializar
        *-- o documento XML atrav�s do m�todo XMLAdapter.ToXML()
        *--
        SELECT Itens
        INDEX ON OrderID TAG OrderID
        SELECT Pedidos
        INDEX ON CustomerID TAG CustomerID
        SET RELATION TO OrderID INTO Itens IN Pedidos
        SET RELATION TO CustomerID INTO Pedidos IN Clientes
        *--
        *-- Configura o objeto XMLAdapter
        *--
        loXA = CREATEOBJECT("XMLAdapter")
        *-- Indica que o aninhamento ser� respeitado no documento XML final
        loXA.RespectNesting = .T.
        *-- Adiciona as tabelas � coleç�o Tables
        loXA.AddTableSchema("Clientes")
        loXA.AddTableSchema("Pedidos")
        loXA.AddTableSchema("Itens")
        *-- Gera um documento XML a partir das tabelas
        loXA.ToXML("\PedidosItens.Xml",,.T.)
        *-- usa o navegador para apresentar os dados do XML
        loBrowser = CREATEOBJECT("InternetExplorer.Application")
        loBrowser.Navigate("\PedidosItens.Xml")
        loBrowser.Visible = .T.
        CATCH TO loExcecao
        MESSAGEBOX("Erro: " + TRANSFORM(loExcecao.ErrorNo) + ". " + loExcecao.Message)
        FINALLY
        IF USED("Clientes")
        USE IN Clientes
        ENDIF
        IF USED("Itens")
        USE IN Itens
        ENDIF
        IF USED("Pedidos")
        USE IN Pedidos
        ENDIF
        CLOSE DATABASES ALL
        STORE Null to loXA, loBrowser
        ENDTRY

Figura 1. Documento XML hier�rquico relacionando tr�s tabelas.

Ambiente Integrado de Desenvolvimento

Um grande benef�cio oferecido aos desenvolvedores VFP a cada nova vers�o do produto consiste nas ferramentas de produtividade, como a Code Referentes, Toolbox, Task Pane e muitas outras. O VFP 9.0 Beta acrescenta uma nova ferramenta, chamada Data Explorer (Figura 2), dispon�vel atrav�s da Task Pane ou da aplicaç�o �DataExplorer.App� no diret�rio-raiz do VFP. A Data Explorer apresenta uma interface bastante completa para os bancos de dados existentes nos servidores SQL Server e fontes de dados nativas ou dispon�veis atrav�s de OLEDB Providers. Uma vez configurada, a conex�o dar� acesso �s tabelas, stored procedures, funç�es e v�rios outros objetos da fonte de dados em quest�o.

Figura 2. Nova ferramenta Data Explorer do Visual FoxPro 9.0 Beta

O mais empolgante de tudo isso � que o c�digo-fonte dessas ferramentas est� totalmente dispon�vel para o desenvolvedor, o que permite estender ainda mais as suas funcionalidades e aprender a efetuar v�rias tarefas interessantes no Visual FoxPro.

No que se refere aos editores de c�digo, O VFP 9.0 Beta suporta compilaç�o em background no momento da ediç�o do c�digo. A sintaxe da instruç�o corrente � destacada para indicar se existem problemas com a formaç�o da mesma.

A janela de propriedades tamb�m recebeu melhorias e conta agora com uma nova guia chamada �Favorites� (favoritos), que permite separar os PEMs de acordo com o gosto do desenvolvedor. Agora, voc� tamb�m pode configurar as fontes e cores de cada tipo de PEM apresentado (Figura 3).

Figura 3. Nova Janela de Propriedades: nova guia �Favorites�; configuraç�o de cores, fontes e a propriedade _MemberData.

Como voc� pode notar na Figura 3, a nova guia �Favorites� pode receber diversos itens e, al�m disso, permite mudar a apresentaç�o dos nomes desses itens, como foi feito com a propriedade customizada �MinhaPropriedade�. Nas vers�es anteriores do VFP, as propriedades e m�todos inclu�dos pelo desenvolvedor eram apresentados em letras min�sculas. No VFP 9.0 Beta, voc� pode especificar como deseja que elas sejam apresentadas. Todo esse n�vel de customizaç�o � poss�vel atrav�s da adiç�o de uma propriedade especial denominada �_MemberData� (Figura 3). Essa propriedade pode conter um documento XML com um vocabul�rio especial que determinar� diversas configuraç�es dos itens da Property Window, permitindo at� que voc� especifique uma aç�o a ser executada quando ocorrer um duplo clique sobre uma propriedade ou m�todo customizado - �timo para um Builder, n�o � mesmo? A Listagem 3 mostra um documento XML simples que pode ser usado como conte�do da propriedade _MemberData.

Listagem 3. Exemplo de um documento XML que pode ser usado na propriedade _MemberData

Interface Gr�fica de Usu�rio

Os formul�rios podem ser �doc�veis� (ancor�veis) e incorporados uns aos outros, como j� acontecia em algumas janelas da IDE das vers�es anteriores;
Agora, o controle TextBox suporta a funcionalidade de �autocomplete� (Figura 4), que habilita a apresentaç�o dos valores anteriormente digitados no campo atrav�s de uma lista de seleç�o. Esse recurso assemelha-se ao existente na Barra de Endereços do navegador Internet Explorer e sua arquitetura abre uma grande gama de possibilidades para customizaç�o;

Figura4. O controle TextBox agora suporta �autocomplete�.
Os controles podem ser ancorados em relaç�o ao seu container, o que evita a necessidade de escrever c�digo para seus eventos �Resize� para rearranj�-los no formul�rio toda vez que este for redimensionado;
Uma outra melhoria que dever� agradar aos veteranos e certamente evitar� muitas d�vidas dos iniciantes � que agora � poss�vel mudar o foco para um novo objeto a partir de um m�todo associado ao evento �Valid�. Isso mesmo! Voc� n�o leu errado! Isto � poss�vel no VFP 9.0 Beta. Voc� s� precisa estar atento para n�o utilizar mais o m�todo SetFocus(), mas sim a cl�usula RETURN seguida de uma refer�ncia ao objeto para o qual voc� deseja dirigir o foco. Por exemplo: RETURN This.Parent.txtCodigo;
Os controles �Line� e �Shape� suportam a montagem de pol�gonos e curvas atrav�s de coordenadas cartesianas que voc� pode passar para a nova propriedade �PolyPoints�. Essas coordenadas ser�o interpretadas como pontos de uma reta ou como determinadores de uma curva de B�zier se a propriedade �LineSlant� possuir o valor �S� ou �s�;
� poss�vel definir a figura a ser apresentada em um controle �Image� simplesmente atribuindo o conte�do bin�rio desta para a nova propriedade �PictureVal� do controle. Obviamente, a fonte de dados para esta propriedade pode ser um campo de uma tabela que suporte conte�do bin�rio, tal como GENERAL NOCPTRANS, ou o novo tipo BLOB. A linha a seguir mostra como esta atribuiç�o pode ser feita diretamente a partir do conte�do bin�rio de um arquivo em disco.

Thisform.imgFoto.PictureVal = FILETOSTR("MinhaFoto.Jpg")

Report Designer

Certamente esta � a �rea que mais foi melhorada nesta nova vers�o do Visual FoxPro. As ferramentas do Report Designer foram praticamente reescritas, e o que � melhor: por meio de c�digo VFP e compiladas em aplicaç�es nativas. Na realidade, a Microsoft criou uma nova arquitetura para o subsistema de relat�rios do VFP 9.0 Beta, o que proporcionar� maior flexibilidade e poder para o desenvolvedor.

Temos novidades tanto nas ferramentas de tempo de projeto quanto nas funcionalidades de tempo de execuç�o. Neste �ltimo caso, a Microsoft incorporou o conceito de �Listeners�. Os �Listeners� s�o objetos que podem �ouvir� os eventos de sa�da da renderizaç�o de um relat�rio. Existem �listeners� padr�es que j� v�m com o produto e os quais podemos estender atrav�s de herança, criando nossos pr�prios listeners customizados e utilizando-os isoladamente ou em cadeia (para que possam ser usados em conjunto). A classe-base �ReportListener� pode ser utilizada facilmente para emitir relat�rios j� existentes, como mostra a Listagem 4:

Listagem 4. Os relat�rios podem ser emitidos atrav�s de um ou mais Listeners.


        oListener = CREATEOBJECT("ReportListener")
        oListener.ListenerType = 1
        REPORT FORM MeuReport.Frx OBJECT oListener

� importante ressaltar que a classe ReportListener possui uma s�rie de PEMs que permitem manipular a forma como o relat�rio ser� emitido. Um dos Listeners padr�o, o XMLListener, � capaz de gerar uma representaç�o da sa�da do relat�rio em formado XML, o que pode facilitar a transmiss�o deste relat�rio para outras plataformas ou mesmo a sua transformaç�o para HTML atrav�s de XSLT, por exemplo.

Recursos da Linguagem

As construç�es WITH ...ENDWITH e FOR... EACH agora suportam Intellisense. Este era um pedido antigo dos usu�rios, desde que estes comandos foram introduzidos no VFP. (Veja a Figura 5).

Figura 5. A construç�o WITH ... ENDWITH agora suporta Intellisense.

Como tradicionalmente acontece a cada nova vers�o do Visual FoxPro, alguns limites tamb�m foram superados no VFP 9.0 Beta, tais como:

Os arrays agora podem ter at� 2 GB em itens � o limite anterior era de 64 KB;
O n�vel m�ximo de aninhamento de procedimentos aumentou para 64.000. O limite anterior era de 128 n�veis;
Os arquivos de programa n�o t�m mais a limitaç�o de tamanho de 64 KB.

Tablet PC

No Visual FoxPro 9.0 Beta, foram incorporadas novas funcionalidades para o trabalho com TabletPCs. A nova propriedade �DisplayOrientation� indica qual a orientaç�o de v�deo do dispositivo, e a nova funç�o ISPEN() identifica se o usu�rio interagiu com a aplicaç�o atrav�s de uma caneta ou n�o.

Conclus�o

Neste artigo, procurei abordar as melhorias mais significativas que ser�o inclu�das na pr�xima vers�o do Visual FoxPro. Diante do grande n�mero de novos recursos e da dificuldade de abordarmos todos eles em um �nico artigo, sugiro que voc� busque mais informaç�es em outros artigos, f�runs de discuss�o, blogs e, obviamente, no Visual FoxPro Developer Center, na MSDN. Ken Levy, o VS Data Product Manager, tem publicado uma s�rie de artigos sobre as novidades da nova vers�o neste site.