Atenç�o: esse artigo tem uma palestra complementar. Clique e assista!

Demais posts desta s�rie:
Construa uma Aplicaç�o 100% OO - Parte 1
Construa uma Aplicaç�o 100% OO - Parte 2
Construa uma Aplicaç�o 100% OO - Parte 3
Construa uma Aplicaç�o 100% OO - Parte 4

Artigo no estilo: Curso

Do que trata o artigo

Metodologias de desenvolvimento de sistemas orientados a objetos (MDS-OO)

T�cnicas de gest�o de projeto

Processo Unificado de Desenvolvimento de Software

UML

Fases e artefatos do projeto de desenvolvimento de sistemas

Para que serve

Uma vis�o pr�tica e realista do desenvolvimento de sistemas orientados a objetos utilizando t�cnicas de gest�o de projetos e de modelagem de sistemas.

Em que situaç�o o tema � �til

Projetos de desenvolvimento de sistema orientados a objeto.

Resumo do DevMan

Construir um pequeno sistema de computador utilizando as mais modernas t�cnicas de gerenciamento de projeto, modelagem orientada a objetos e uma metodologia de desenvolvimento de sistemas com aborda�gem iterativa e incremental.

Este artigo tem o objetivo de demonstrar a execuç�o de um projeto de desenvolvimento de sistema sob a �tica da engenharia de software, fazendo uso do desenvolvimento orientado a objetos. Nesta quinta e �ltima parte, chegamos � implementaç�o do c�digo-fonte, que permitir� compreender como ocorre a transformaç�o do abstrato para o concreto, do modelo para o c�digo implementado.

Nas partes anteriores, modelamos o processo de neg�cio que ser� suportado pelo sistema em desenvolvimento, empregando t�cnicas de levantamento de dados atrav�s da observaç�o direta e da entrevista com o cliente. A modelagem do processo de neg�cio deu origem aos requisitos funcionais e n�o funcionais do sistema e a construç�o de uma proposta de soluç�o, materializada no prot�tipo do sistema.

Passamos ent�o para a especificaç�o de casos de uso, diagramas de atividades e classes, sempre focados na evoluç�o gradativa da soluç�o, passamos pela soluç�o arquitetural e chegamos, finalmente, � implementaç�o do c�digo, que ser� abordada nessa parte do artigo.

A Implementaç�o

Com o amadurecimento do modelo proposto e tomadas as decis�es pertinentes � arquitetura, infraestrutura, ambiente de servidor de aplicaç�o e banco de dados, ferramentas e linguagem de desenvolvimento, estamos aptos a iniciar a fase de implementaç�o.

A implementaç�o � a etapa (disciplina) respons�vel pela construç�o dos scripts de criaç�o da estrutura do banco de dados, pela construç�o do c�digo-fonte do aplicativo e pela execuç�o dos testes, tendo como entrada os artefatos elaborados nas fases anteriores.

Para a codificaç�o, nesse artigo, utilizaremos o Microsoft Visual Web Developer 2008 Express Edition, uma vers�o freeware do Visual Studio 2008, e a linguagem Visual Basic. Como sistema gerenciador de banco de dados utilizaremos o Firebird Server 2.1.1, um excelente sistema de banco de dados padr�o SQL de c�digo aberto (open source).

Nota

O servidor de banco de dados Firebird Server pode ser obtido no site oficial do projeto, http://www.firebirdsql.org, e pode ser livremente instalado e utilizado em servidores ou estaç�es de trabalho das principais plataformas do mercado: Win32, Win64, Linux x86, Linux AMD64, MacOSX e Solaris.

Estrutura de pacotes do projeto

Começaremos a implementaç�o pela criaç�o, no Visual Studio, de dois novos projetos: Um projeto web, que chamamos neste exemplo de SCRMweb, para a camada de apresentaç�o e um projeto biblioteca de classes (class library), chamado SCRMsrv, para a camada de neg�cio e de persist�ncia. Os dois projetos estar�o contidos em uma soluç�o denominada SCRM. A Figura 1 apresenta a janela Solution Explorer, com a estrutura dos projetos e os respectivos arquivos de programas implementados.

Figura 1. Estrutura de projetos

Para criar a estrutura de projeto proposta, abra o Visual Studio e, no menu File, selecione a opç�o New Project. No quadro Project Types, selecione a linguagem de programaç�o a ser utilizada (Visual Basic) e o tipo do primeiro projeto a ser criado (Windows). No quadro Templates, selecione o modelo Class Library. Os demais campos devem ser preenchidos conforme exemplificado na Figura 2. Com esse procedimento criaremos a soluç�o SCRM e o projeto SCRMsrv, sendo necess�rio ainda que adicionemos � soluç�o um novo projeto ASP.Net Web Application, nomeado como SCRMweb.

Figura 2. Criando a ClassLibrary

Os arquivos de programa (classes) do projeto SCRMsrv foram fisicamente organizados em uma estrutura composta por tr�s pastas (subdiret�rios) e logicamente identificados por pacotes (namespaces) an�logos �s pastas criadas. O projeto foi estruturado da seguinte forma:

� Modelo: Composto de classes que representam as entidades de neg�cio do sistema, sendo, portanto, constitu�das por atributos privados (private) e propriedades p�blicas (public property), respons�veis pela exposiç�o dos dados da classe (m�todos getters e setters).

Neg�cio: Composto por classes p�blicas com m�todos, igualmente p�blicos, respons�veis pelo comportamento e aplicaç�o das regras de neg�cio. Essas classes n�o possuem atributos e seus m�todos podem receber e/ou retornar as classes (ou coleç�es de classes) do pacote Modelo.
Integraç�o: Nesse pacote ser�o escritas as classes respons�veis pela interaç�o com o sistema de banco de dados, que controlam as conex�es, executam as instruç�es SQL e retornam o resultado para o pacote Neg�cio, que sempre ser� o acionador dos m�todos do pacote Integraç�o. As classes do pacote Integraç�o ser�o de visibilidade privativa �s classes do projeto (friend).

A estrutura de projeto criada nesses primeiros passos da etapa de implementaç�o est� em conformidade com o Diagrama de Pacotes apresentado e discutido na parte 4 deste artigo.

Construindo a camada de neg�cios e dados

Ao longo da modelagem do sistema � Requisitos, An�lise e Projeto � foram confeccionados artefatos (documentos de texto, planilhas e diagramas), previstos na metodologia de desenvolvimento de sistemas adotada, com o objetivo de documentar o sistema e apoiar o trabalho dos projetistas envolvidos.

Comentamos tamb�m, mais de uma vez, que durante a etapa de implementaç�o muitos dos artefatos de an�lise e projeto seriam quase que diretamente convertidos em linhas de c�digo. A criaç�o autom�tica de c�digo a partir de modelos UML � uma realidade de mercado e uma grande vantagem, n�o apenas para ganhar produtividade e facilitar a vida do codificador, mas, principalmente, para garantir o sincronismo da documentaç�o com o c�digo. Praticamente todas as ferramentas de modelagem, incluindo as gratuitas, possuem, pelo menos, a capacidade de gerar o c�digo a partir do modelo (forward engineering). Algumas ferramentas mais sofisticadas possuem ainda a capacidade de transformaç�o bidirecional de modelo e c�digo, de forma que podemos alterar o modelo e visualizar o c�digo resultante, assim como alterar o c�digo e visualizar as respectivas alteraç�es no modelo.

Em nosso artigo utilizamos o StarUML, uma ferramenta gratuita de modelagem que realiza a transformaç�o unidirecional do modelo em c�digo C#, C++ e Java. Optamos por construir nossa aplicaç�o em VB.Net e, por isso, geraremos nosso c�digo manualmente, iniciando pela construç�o das classes do pacote de modelo. As classes do pacote Modelo, como explicado anteriormente, representam entidades de neg�cio. Na Listagem 1 podemos visualizar o c�digo-fonte da classe referente � entidade grupo de recursos.

Listagem 1. Classe GrupoRecursos

Namespace Modelo
     Public Class GrupoRecursos
  
         Private numId As Integer
         Public Property id() As Integer
             Get
                 Return numId
             End Get
             Set(ByVal value As Integer)
                 numId = value
             End Set
         End Property
  
         Private strDescricao As String
         Public Property descricao() As String
             Get
                 Return strDescricao
             End Get
             Set(ByVal value As String)
                 strDescricao = value
             End Set
         End Property
  
         Private strNatureza As Natureza
         Public Property natureza() As Natureza
             Get
                 Return strNatureza
             End Get
             Set(ByVal value As Natureza)
                 strNatureza = value
             End Set
         End Property
  
     End Class
 End Namespace

Podemos observar, logo na primeira linha da Listagem 1, que foi inclu�da a declaraç�o Namespace com o nome do pacote correspondente, no caso, Modelo. A seguir, encontramos a declaraç�o da classe como p�blica (public). Observe tamb�m que essa classe � composta apenas por vari�veis locais privadas (private) e propriedades p�blicas. O mesmo procedimento ser� realizado para as demais entidades identificadas no modelo do projeto.

O pr�ximo passo � a criaç�o das classes do pacote de integraç�o. Essas classes possuem a responsabilidade de estabelecer a ligaç�o (integraç�o) com o gerenciador de banco de dados. A primeira classe do pacote de integraç�o ser� a classe GrupoRecursosDAO, exibida na Listagem 2.

Listagem 2. Classe GrupoRecursosDAO

Namespace Integracao
  
     ''' Classe de manipulaç�o do banco de dados
     Friend Class GrupoRecursosDAO
  
         Private Sub New()
         End Sub
  
         ''' Recupera do banco de dados do sistema um objeto GrupoRecursos
         ''' C�digo do grupo de recursos
         ''' Objeto GrupoRecursos recuperado
         Public Shared Function ObterObjeto(ByVal id As Integer) As Modelo.GrupoRecursos
             Dim objDBMediator = Integracao.DBMediatorFactory.ObterDBMediator
             Dim objComando = objDBMediator.Command("SELECT * FROM GrupoRecursos WHERE grpID = @grpID")
             Dim objDataReader As Data.IDataReader
             Dim objGrupoRecursos As Modelo.GrupoRecursos = Nothing
             objComando.Parameters.Add(objDBMediator.Parameter("@grpID", id))
             objDataReader = objDBMediator.MontaReader(objComando)
             If objDataReader.Read Then
                 objGrupoRecursos = MontaObjeto(objDataReader)
             End If
             objDataReader.Close()
             objDataReader.Dispose()
             objDataReader = Nothing
             Return objGrupoRecursos
         End Function
  
         ''' Recupera do banco de dados do sistema um objeto GrupoRecursos
         ''' Descriç�o do grupo de recursos
         ''' Objeto GrupoRecursos recuperado
         Public Shared Function ObterObjeto(ByVal descricao As String) As Modelo.GrupoRecursos
             Dim objDBMediator = Integracao.DBMediatorFactory.ObterDBMediator
             Dim objComando = objDBMediator.Command("SELECT * FROM GrupoRecursos WHERE grpDescricao =
          @grpDescricao")
             Dim objDataReader As Data.IDataReader
             Dim objGrupoRecursos As Modelo.GrupoRecursos = Nothing
             objComando.Parameters.Add(objDBMediator.Parameter("@grpDescricao", descricao))
             objDataReader = objDBMediator.MontaReader(objComando)
             If objDataReader.Read Then
                 objGrupoRecursos = MontaObjeto(objDataReader)
             End If
             objDataReader.Close()
             objDataReader.Dispose()
             objDataReader = Nothing
             Return objGrupoRecursos
         End Function
  
         ''' Recupera um coleç�o de objetos GrupoRecursos
         ''' Coleç�o de objetos GrupoRecursos
         Public Shared Function Listar() As List(Of Modelo.GrupoRecursos)
             Dim objDBMediator = Integracao.DBMediatorFactory.ObterDBMediator
             Dim objComando = objDBMediator.Command("SELECT * FROM GrupoRecursos ORDER BY grpDescricao")
             Dim objDataReader As Data.IDataReader
             Dim listGrupoRecursos As List(Of Modelo.GrupoRecursos) = New List(Of Modelo.GrupoRecursos)
             objDataReader = objDBMediator.MontaReader(objComando)
             While objDataReader.Read
                 listGrupoRecursos.Add(MontaObjeto(objDataReader))
             End While
             objDataReader.Close()
             objDataReader.Dispose()
             objDataReader = Nothing
             Return listGrupoRecursos
         End Function
  
         Private Shared Function MontaObjeto(ByRef objDataReader As Data.IDataReader) As Modelo.GrupoRecursos
             Dim objGrupoRecursos As Modelo.GrupoRecursos = New Modelo.GrupoRecursos()
             objGrupoRecursos.id = objDataReader("grpID")
             objGrupoRecursos.descricao = objDataReader("grpDescricao")
             objGrupoRecursos.natureza = objDataReader("grpNatureza")
             Return objGrupoRecursos
         End Function
  
         ''' Recupera a quantidade de recursos associados a um determinado grupo de recursos
         ''' C�digo de identificaç�o do grupo de recursos a ser exclu�do do banco de dados
         ''' N�mero inteiro referente � quantidade de recursos associados ao grupo de recursos
         Public Shared Function ObterQtdRecursosAssociados(ByVal id As Integer) As Integer
             Dim objDBMediator = Integracao.DBMediatorFactory.ObterDBMediator
             Dim objComando = objDBMediator.Command("SELECT COUNT(*) FROM Recurso WHERE grpID = @grpID")
             objComando.Parameters.Add(objDBMediator.Parameter("@grpID", id))
             Return objDBMediator.MontaScalar(objComando)
         End Function
  
         ''' Adiciona um novo grupo de recursos ao banco de dados do sistema
         ''' Objeto GrupoRecursos a ser adicionado ao banco de dados
         ''' Objeto GrupoRecursos adicionado
         Public Shared Function Incluir(ByVal objGrupoRecursos As Modelo.GrupoRecursos) As Modelo.GrupoRecursos
             Dim objDBMediator = Integracao.DBMediatorFactory.ObterDBMediator
             Dim objComando = objDBMediator.Command("SELECT * FROM Add_GrupoRecursos(@grpDescricao,
          @grpNatureza)")
             objComando.Parameters.Add(objDBMediator.Parameter("@grpDescricao", objGrupoRecursos.descricao))
             objComando.Parameters.Add(objDBMediator.Parameter("@grpNatureza", objGrupoRecursos.natureza))
             Try
                 objGrupoRecursos.id = objDBMediator.MontaScalar(objComando)
                 Return objGrupoRecursos
             Catch ex As Exception
                 Return Nothing
             End Try
         End Function
  
         ''' Altera um grupo de recursos do banco de dados do sistema
         ''' Objeto GrupoRecursos a ser alterado no banco de dados
         ''' True se a alteraç�o foi realizada com sucesso e False se ocorreu algum erro
         Public Shared Function Alterar(ByVal objGrupoRecursos As Modelo.GrupoRecursos) As Boolean
             Dim objDBMediator = Integracao.DBMediatorFactory.ObterDBMediator
             Dim objComando = objDBMediator.Command("UPDATE GrupoRecursos SET grpDescricao = @grpDescricao,
          grpNatureza = @grpNatureza WHERE grpID = @grpID")
             objComando.Parameters.Add(objDBMediator.Parameter("@grpDescricao", objGrupoRecursos.descricao))
             objComando.Parameters.Add(objDBMediator.Parameter("@grpNatureza", objGrupoRecursos.natureza))
             objComando.Parameters.Add(objDBMediator.Parameter("@grpID", objGrupoRecursos.id))
             Try
                 objDBMediator.ExecutaQuery(objComando)
                 Return True
             Catch ex As Exception
                 Return False
             End Try
         End Function
  
         ''' Exclui um grupo de recursos ao banco de dados do sistema
         ''' C�digo de identificaç�o do grupo de recursos a ser exclu�do do banco de dados
         ''' True se a exclus�o foi realizada com sucesso ou False se ocorreu algum erro
         Public Shared Function Excluir(ByVal id As Integer) As Boolean
             Dim objDBMediator = Integracao.DBMediatorFactory.ObterDBMediator
             Dim objComando = objDBMediator.Command("DELETE FROM GrupoRecursos WHERE grpID = @grpID")
             objComando.Parameters.Add(objDBMediator.Parameter("@grpID", id))
             Try
                 objDBMediator.ExecutaQuery(objComando)
                 Return True
             Catch ex As Exception
                 Return False
             End Try
         End Function
  
     End Class
 End Namespace

A classe GrupoRecursosDAO, logo na primeira linha, possui a declaraç�o do Namespace e a identificaç�o do pacote Integraç�o. A quarta linha inicia com a declaraç�o Friend, restringindo a visibilidade da classe as outras classes e objetos do assembly que ser� gerado.

O uso de tags de documentaç�o � um boa pr�tica. Para tanto, observe que todos os m�todos (functions e subs) da classe s�o precedidos de linhas de coment�rio com tags de documentaç�o XML. Essas linhas s�o sempre iniciadas por tr�s aspas simples (ap�strofos), seguidos por tags com a descriç�o resumida do m�todo (summary), a identificaç�o e a descriç�o dos par�metros (param) e, no caso de funç�es, com o retorno (returns) que devem ser esperados. Esse tipo de documentaç�o � especialmente �til em m�todos p�blicos, que ser�o utilizados por outros m�todos, por serem reconhecidos pelo Visual Studio e exibidos pelo IntelliSense durante a ediç�o do c�digo-fonte.

Para finalizar a organizaç�o dos pacotes da biblioteca de classes SCRMsrv, ser� criado o pacote Negocio para os objetos de neg�cio (Business Object) da aplicaç�o. Criaremos a classes GrupoRecursosBO, exibida na Listagem 3.

Listagem 3. Classe GrupoRecursosBO

Namespace Negocio
  
     ''' Classe para validaç�o de regras de neg�cio
     Public Class GrupoRecursosBO
  
         ''' Recupera os dados de um objeto GrupoRecursos
         ''' C�digo do grupo de recursos
         ''' Objeto GrupoRecursos recuperado
         Public Shared Function ObterObjeto(ByVal grupoID As Integer) As Modelo.GrupoRecursos
             Return Integracao.GrupoRecursosDAO.ObterObjeto(grupoID)
         End Function
  
         ''' Recupera os dados de um objeto GrupoRecursos
         ''' Descriç�o do grupo de recursos
         ''' Objeto GrupoRecursos recuperado
         Public Shared Function ObterObjeto(ByVal descricao As String) As Modelo.GrupoRecursos
             Return Integracao.GrupoRecursosDAO.ObterObjeto(descricao)
         End Function
  
         ''' Recupera um coleç�o de objetos GrupoRecursos
         ''' Coleç�o de objetos GrupoRecursos
         Public Shared Function Listar() As List(Of Modelo.GrupoRecursos)
             Return Integracao.GrupoRecursosDAO.Listar()
         End Function
  
         ''' Adiciona um novo grupo de recursos ao banco de dados do sistema
         ''' Objeto GrupoRecursos a ser adicionado ao banco de dados
         ''' Objeto GrupoRecursos adicionado
         Public Shared Function Incluir(ByRef objGrupoRecursos As Modelo.GrupoRecursos) As List(Of String)
             Dim strMsgs As List(Of String) = New List(Of String)
             If Not RN06(objGrupoRecursos.descricao) Then
                 strMsgs.Add(TipoExcecaoBO.GrupoRecursosIncluir_DescricaoRepetida.ToString)
             Else
                 objGrupoRecursos = Integracao.GrupoRecursosDAO.Incluir(objGrupoRecursos)
                 If objGrupoRecursos Is Nothing Then
                     strMsgs.Add(TipoExcecaoBO.GrupoRecursosIncluir_Falha.ToString)
                 End If
             End If
             Return strMsgs
         End Function
  
         ''' Altera um grupo de recursos do banco de dados do sistema
         ''' Objeto GrupoRecursos a ser alterado no banco de dados
         ''' Resultado da operaç�o de alteraç�o
         Public Shared Function Alterar(ByVal objGrupoRecursos As Modelo.GrupoRecursos) As List(Of String)
             Dim strMsgs As List(Of String) = New List(Of String)
             If Not RN06(objGrupoRecursos) Then
                 strMsgs.Add(TipoExcecaoBO.GrupoRecursosAlterar_DescricaoRepetida.ToString)
             ElseIf Integracao.GrupoRecursosDAO.Alterar(objGrupoRecursos) = False Then
                 strMsgs.Add(TipoExcecaoBO.GrupoRecursosAlterar_Falha.ToString)
             End If
             Return strMsgs
         End Function
  
         ''' Exclui um grupo de recursos ao banco de dados do sistema
         ''' C�digo de identificaç�o do grupo de recursos a ser exclu�do do banco de dados
         ''' Resultado da operaç�o de exclus�o
         Public Shared Function Excluir(ByVal grupoID As Integer) As List(Of String)
             Dim strMsgs As List(Of String) = New List(Of String)
             If Not RN01(grupoID) Then strMsgs.Add(TipoExcecaoBO.GrupoRecursosExcluir_RecursosAssociados.ToString)
             If Not RN02(grupoID) Then strMsgs.Add(TipoExcecaoBO.GrupoRecursosExcluir_ReservasFuturas.ToString)
             If strMsgs.Count = 0 Then
                 If Integracao.GrupoRecursosDAO.Excluir(grupoID) = False Then
                     strMsgs.Add(TipoExcecaoBO.GrupoRecursosExcluir_Falha.ToString)
                 End If
             End If
             Return strMsgs
         End Function
  
         ''' Validar a exclus�o de grupo de recursos com recursos associados
         Private Shared Function RN01(ByVal grupoID As Integer) As Boolean
             If Integracao.GrupoRecursosDAO.ObterQtdRecursosAssociados(grupoID) > 0 Then
                 Return False
             Else
                 Return True
             End If
         End Function
  
         ''' Validar a exclus�o de grupo de recursos com reservas futuras
         Private Shared Function RN02(ByVal grupoID As Integer) As Boolean
             'TODO: Implementar verificaç�o da exist�ncia de solicitaç�es de reservas para datas futuras
             Return True
         End Function
  
         ''' Validar a duplicidade da descriç�o do grupo de recursos
         Private Shared Function RN06(ByVal objGrupoNew As Modelo.GrupoRecursos) As Boolean
             Dim objGrupoOld As Modelo.GrupoRecursos = Integracao.GrupoRecursosDAO.
          ObterObjeto(objGrupoNew.descricao)
             If objGrupoOld Is Nothing Then
                 Return True
             Else
                 If objGrupoOld.id = objGrupoNew.id Then
                     Return True
                 Else
                     Return False
                 End If
             End If
         End Function
  
         ''' Validar a duplicidade da descriç�o do grupo de recursos
         Private Shared Function RN06(ByVal descricao As String) As Boolean
             Dim objGrupoOld As Modelo.GrupoRecursos = Integracao.GrupoRecursosDAO.ObterObjeto(descricao)
             If objGrupoOld Is Nothing Then
                 Return True
             Else
                 Return False
             End If
         End Function
  
     End Class
 End Namespace
 <p align="left">

Al�m das peculiaridades comentadas anteriormente (declaraç�o Namespace, visibilidade da classe e uso de tags de documentaç�o XML), podemos observar que a classe � composta por m�todos p�blicos, respons�veis pelo comportamento, e por funç�es privadas, respons�veis pela implementaç�o de regras de neg�cio. Os m�todos privados relativos �s regras de neg�cio, por uma quest�o de compatibilidade com a documentaç�o do projeto, foram nomeados com a mesma identificaç�o do artefato de especificaç�o de regras de neg�cio, apresentado na parte 2 deste artigo. Desta forma, a RN01 ser� implementada no m�todo RN01, facilitando a rastreabilidade do c�digo, o que ser� muito �til em futuras manutenç�es evolutivas e corretivas.

A funç�o privada RN02, linhas 80 a 83, implementa a regra de neg�cio que validar� a exclus�o de um grupo de recurso com reservas futuras. Essa regra de neg�cio, apesar de ter sido identificada e especificada durante a fase de an�lise de requisitos (vide parte 2 desse artigo), somente ser� detalhada durante a pr�xima iteraç�o do projeto, n�o havendo, nesse momento, informaç�es suficientes para realizarmos sua construç�o. Nesse caso, a funç�o foi criada de maneira que retornar� sempre verdadeiro (true), o que possibilita seu uso pelo restante do sistema, mesmo que sem efeito. Quando forem obtidas as informaç�es necess�rias, retornaremos a esse arquivo e incrementaremos a funç�o, sem a necessidade de alterar o restante do c�digo. Essa � uma pr�tica comum sempre que trabalhamos com um m�todo de desenvolvimento que seja iterativo e incremental.

Inclu�mos ainda nessa funç�o uma linha de coment�rio com a palavra chave �TODO� (do ingl�s, To Do � A Fazer). Essa linha de coment�rio far� com que o Visual Studio adicione uma entrada na lista de tarefas �Comments� com o texto da linha de coment�rio, permitindo a r�pida e f�cil localizaç�o do que est� pendente em nosso c�digo-fonte.

Nossa camada de neg�cios � composta ainda por outros arquivos de programas correspondentes �s entidades Recurso e Usu�rio e aos componentes relacionados, tendo sido implementado, ao todo, 13 arquivos de programa. Por motivos �bvios n�o abordaremos nesse artigo a construç�o das demais classes da camada de neg�cio (Business Objects e Modelos) devido �s similaridades existentes.

As classes implementadas s�o de complexidade baixa, com uma arquitetura modular que nos possibilitou ter m�todos bastante coesos e, por consequ�ncia, bastante simples. Para a construç�o do material desse artigo foi alocado um programador experiente que implementou os 13 arquivos de programa dessa camada em apenas um dia de trabalho. Isso foi poss�vel porque visamos uma documentaç�o clara e consistente, al�m de adotarmos uma arquitetura s�lida e padronizada.

Construindo a camada de apresentaç�o

A camada de apresentaç�o, conforme abordado na parte 4 desse artigo, poder� ser implementada em um aplicativo independente da camada de neg�cios, graças a alta reusabilidade obtida com a arquitetura do sistema, que isolou a camada de neg�cios em uma aplicaç�o distinta. Poder�amos, por exemplo, criar tamb�m uma aplicaç�o para dispositivos m�veis, na plataforma Java ME, que reutilizasse a camada de neg�cios constru�da. Poder�amos ainda agregar � nossa camada de neg�cios uma interface WCF (Windows Communication Foundation), para que a camada de neg�cios pudesse ser hospedada em um computador e a camada de apresentaç�o web pudesse ser hospedada em outro computador, um servidor de aplicaç�o. Estar�amos ent�o operando em um ambiente distribu�do e de alta escalabilidade, sem a necessidade de implementar grandes mudanças no c�digo do sistema.

Devemos lembrar tamb�m que durante a an�lise de requisitos foi constru�do um prot�tipo da soluç�o proposta (vide parte 2 desse artigo). Na codificaç�o do prot�tipo, utilizamos uma arquitetura em camadas, no padr�o MVC, no intuito de reutilizar as p�ginas web durante a implementaç�o da camada de apresentaç�o na fase de construç�o do sistema.

Criamos, no Visual Studio, a soluç�o SCRM, que cont�m o projeto SCRMweb, nossa camada de apresentaç�o. Para reutilizar o prot�tipo, devemos copiar para o diret�rio da aplicaç�o os arquivos das p�ginas web (aspx e aspx.vb), da folha de estilo (principal.css) e da master page (principal.master). Os arquivos foram copiados de um diret�rio para o outro porque agora podemos atualiz�-los, mantendo o prot�tipo na situaç�o original, aprovada pelo cliente.

Começaremos pela implementaç�o da rotina de CRUD (Create, Read, Update and Delete) do cadastro de grupos de recursos. No arquivo GrupoRecursosLista.aspx, que apresenta um grid com os grupos de recursos cadastrados, precisaremos reconfigurar o controle ObjectDataSource, alterando as propriedades TypeName e SelectMethod, para que apontem para a classe GrupoRecursosBO, da camada de neg�cios, e o m�todo Listar, respectivamente. O controle ficar� da seguinte forma:

 SelectMethod="Listar" TypeName=
         "SCRMsrv.Negocio.
             GrupoRecursosBO" />

Precisamos ainda incluir o tratamento para alguns dos eventos da p�gina, como por exemplo, o click nos bot�es da p�gina. Na Listagem 4 vemos o code-behind correspondente.

Listagem 4. Arquivo GrupoRecursosLista.aspx.vb

Imports SCRMsrv
  
 Partial Class GrupoRecursosLista
     Inherits System.Web.UI.Page
  
     Protected Sub grdGrupoRecursos_RowDataBound(ByVal sender As Object, _
          ByVal e As System.Web.UI.WebControls.GridViewRowEventArgs) _
          Handles grdGrupoRecursos.RowDataBound
         If e.Row.RowType = DataControlRowType.DataRow Then
             Dim objGrupoRecursos As Modelo.GrupoRecursos = e.Row.DataItem
             Dim btnAlterar As ImageButton = e.Row.FindControl("btnAlterar")
             Dim btnExcluir As ImageButton = e.Row.FindControl("btnExcluir")
             e.Row.Cells(1).Text = Enumeration.getName(GetType(Modelo.Natureza), objGrupoRecursos.natureza.ToString)
             btnAlterar.AlternateText = String.Format(Resources.Labels.Grupo_btnAlterar_Alt, objGrupoRecursos.descricao)
             btnAlterar.CommandArgument = objGrupoRecursos.id
             btnExcluir.AlternateText = String.Format(Resources.Labels.Grupo_btnExcluir_Alt, objGrupoRecursos.descricao)
             btnExcluir.CommandArgument = objGrupoRecursos.id
             btnExcluir.OnClientClick = String.Format("return confirm('')", _
          String.Format(Resources.Labels.Grupo_btnExcluir_Confirm, objGrupoRecursos.descricao))
         End If
     End Sub
  
     Protected Sub grdGrupoRecursos_RowCommand(ByVal sender As Object, _
          ByVal e As System.Web.UI.WebControls.GridViewCommandEventArgs) _
          Handles grdGrupoRecursos.RowCommand
         If e.CommandName = "Excluir" Then
             ExcluiGrupo(e.CommandArgument)
         ElseIf e.CommandName = "Alterar" Then
             Server.Transfer(String.Format("GrupoRecursosFicha.aspx?action=&id=", _
          +ActionType.Alterar, e.CommandArgument))
         End If
     End Sub
  
     Protected Sub btnIncluir_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles btnIncluir.Click
         Server.Transfer(String.Format("GrupoRecursosFicha.aspx?action=", +ActionType.Incluir))
     End Sub
  
     Private Sub ExcluiGrupo(ByVal grupoID As Integer)
         Dim objGrupoRecursos As Modelo.GrupoRecursos = Negocio.GrupoRecursosBO.ObterObjeto(grupoID)
         Dim strMsgs As List(Of String) = Negocio.GrupoRecursosBO.Excluir(grupoID)
         Me.blstMensagem.Items.Clear()
         If strMsgs.Count > 0 Then
             Me.blstMensagem.CssClass = "validatorErro"
             Me.blstMensagem.DataSource = MsgErro.ConverteExcecaoBO(strMsgs)
             Me.blstMensagem.DataBind()
         Else
             strMsgs.Add(String.Format(Resources.Mensagens.SUC004, objGrupoRecursos.descricao))
             Me.blstMensagem.CssClass = "validatorSucesso"
             Me.blstMensagem.DataSource = strMsgs
             Me.blstMensagem.DataBind()
             Me.grdGrupoRecursos.DataBind()
         End If
     End Sub
 End Class

Para concluir a rotina de cadastro do grupo de recursos precisamos atualizar a ficha de cadastro. O prot�tipo o arquivo GrupoRecursosFicha.aspx possui um controle DropDownList com dois itens fixados no pr�prio controle. A configuraç�o do controle deve ser alterada para que possamos recuperar o conte�do da coleç�o Natureza. Incluiremos tamb�m o tratamento de eventos da p�gina. A Listagem 5 apresenta o code-behind da p�gina.

Listagem 5. Arquivo GrupoRecursosFicha.aspx.vb

Imports SCRMsrv
  
 Partial Class GrupoRecursosFicha
     Inherits System.Web.UI.Page
  
     Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
         If Not Page.IsPostBack Then
             Dim numAcao As ActionType = Request.QueryString("action")
             If numAcao = ActionType.Alterar Then
                 Dim numId As Integer = Request.QueryString("id")
                 Dim objGrupo As SCRMsrv.Modelo.GrupoRecursos =
                    SCRMsrv.Negocio.GrupoRecursosBO.ObterObjeto(numId)
                 If objGrupo IsNot Nothing Then
                     PopulaNatureza()
                     Me.txtDescricao.Text = objGrupo.descricao
                     Me.cboNatureza.SelectedValue = objGrupo.natureza
                     Me.txtDescricao.Focus()
                     ViewState("action") = ActionType.Alterar
                     ViewState("id") = numId
                 End If
             ElseIf numAcao = ActionType.Incluir Then
                 PopulaNatureza()
                 Me.txtDescricao.Focus()
                 ViewState("action") = ActionType.Incluir
             Else
                 Server.Transfer("AcessoInvalido.htm")
             End If
         End If
     End Sub
  
     Private Sub PopulaNatureza()
         Me.cboNatureza.DataSource = Enumeration.getNames(GetType(SCRMsrv.Modelo.Natureza))
         Me.cboNatureza.DataValueField = "value"
         Me.cboNatureza.DataTextField = "name"
         Me.cboNatureza.DataBind()
     End Sub
  
     Protected Sub btnOk_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles btnOk.Click
         Dim strMsgs As List(Of String) = New List(Of String)
         Dim strMsgSucesso As String
         Dim objGrupoRecursos As Modelo.GrupoRecursos = New Modelo.GrupoRecursos()
         objGrupoRecursos.descricao = Me.txtDescricao.Text.Trim
         objGrupoRecursos.natureza = Me.cboNatureza.SelectedValue
         Me.blstMensagem.Items.Clear()
         If ViewState("action") = ActionType.Incluir Then
             strMsgSucesso = Resources.Mensagens.SUC001
             strMsgs = Negocio.GrupoRecursosBO.Incluir(objGrupoRecursos)
             If strMsgs.Count = 0 Then Me.btnOk.Enabled = False
         ElseIf ViewState("action") = ActionType.Alterar Then
             strMsgSucesso = Resources.Mensagens.SUC002
             objGrupoRecursos.id = ViewState("id")
             strMsgs = Negocio.GrupoRecursosBO.Alterar(objGrupoRecursos)
         Else
             Server.Transfer("AcessoInvalido.htm")
             Exit Sub
         End If
         If strMsgs.Count > 0 Then
             Me.blstMensagem.CssClass = "validatorErro"
             Me.blstMensagem.DataSource = MsgErro.ConverteExcecaoBO(strMsgs)
             Me.blstMensagem.DataBind()
         Else
             strMsgs.Add(strMsgSucesso)
             Me.blstMensagem.CssClass = "validatorSucesso"
             Me.blstMensagem.DataSource = strMsgs
             Me.blstMensagem.DataBind()
         End If
     End Sub
 
 
     Protected Sub btnCancelar_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles btnCancelar.Click
         Server.Transfer("~/GrupoRecursosLista.aspx")
     End Sub
  
 End Class

Com muito pouco esforço incrementamos o prot�tipo e implementamos a camada de apresentaç�o. A rotina de cadastro completa, composta por quatro arquivos de programas, foi implementada por um programador experiente com apenas duas horas de trabalho. Poder�amos ainda ter alocado dois profissionais, um para implementar a biblioteca de classes (SCRMsrv) e outro para implementar a camada de apresentaç�o (SCRMweb), em paralelo, reduzindo a duraç�o total do cronograma do projeto.

Por �ltimo, vemos que a reutilizaç�o do prot�tipo garantiu tamb�m a integridade entre o que foi prototipado, avaliado e aprovado pelo cliente e o produto final, que por consequ�ncia ser� mais facilmente aprovado.

Nota

Os artefatos de projeto, arquivos de c�digo-fonte, scripts de definiç�o de estruturas de banco de dados e todo o material confeccionado durante o desenvolvimento do sistema de controle de recursos materiais, objeto de estudo desse artigo, est� dispon�vel para download no site da DevMedia.

Conclus�o

Ao longo deste artigo, organizado em cinco partes (mas t�nhamos assunto para muito mais), desnudamos o processo de desenvolvimento de um sistema real e fact�vel. Começamos com o termo de abertura do projeto de desenvolvimento e com a declaraç�o de escopo e conclu�mos, nessa �ltima parte, com a implementaç�o do c�digo-fonte de uma iteraç�o completa. Navegamos pelo mundo da engenharia de software e da modelagem de sistemas, passando do abstrato ao concreto, do artefato ao c�digo implementado e testado.

O artigo foi escrito a quatro m�os, por dois profissionais que t�m em comum o entusiasmo pela engenharia de software, mas com conhecimentos espec�ficos distintos, que se somaram. Um especialista em tecnologia .Net e o outro um pesquisador de Java e software livre. A parceria entre dois universos paralelos foi poss�vel porque a engenharia de software e as metodologias de desenvolvimento orientadas a objeto s�o perenes e independentes dos padr�es tecnol�gicos e dos modismos do mercado. Chegamos at� mesmo a discutir, como uma provaç�o adicional, a publicaç�o de duas vers�es dessa �ltima parte do artigo, uma na plataforma .Net e outra em Java. Acabamos desistindo (por enquanto).

Desejamos fechar essa �ltima parte do artigo com a mesma frase que abriu muitas das partes anteriores � Programar � divertido, mas desenvolver sistemas com qualidade � dif�cil � tal como um mantra, buscando criar a transformaç�o para o crescimento daqueles que nos l�em.

Nota do DevMan

Nesse artigo foi utilizado o BrOffice.org para a elaboraç�o dos textos, o Microsoft Visual Web Developer 2008 Express Edition como ferramenta de desenvolvimento, o IBExpert Personal Edition da HK Software como ferramenta de gerenciamento do banco de dados e o Firebird Server 2.1.1 como gerenciador de banco de dados. Todas essas ferramentas s�o gratuitas.

Refer�ncias Bibliogr�ficas

Larman, Craig. 2002. Applying UML and Patterns: An Introduction to Object-Oriented Analysis and Design and the Uni�fied Process. Second Edition. Prentice Hall PTR.

V�rios. 2007. Metodologia de Desenvolvimento de Projetos da Dataprev: Paradigma da Orientaç�o a Objetos � Vers�o 3.1.

V�rios. 2007. Implementing Data Transfer Object in .NET with a DataSet.
http://msdn2.microsoft.com/en-us/library/ms998527.aspx

V�rios. 2007. Implementing Data Transfer Object in .NET with a Typed DataSet.
http://msdn2.microsoft.com/en-us/library/ms998529.aspx

V�rios. 2007. Data Transfer Object.
http://msdn2.microsoft.com/en-us/library/ms978717.aspx

Chiba, Cl�udio e Nardi, Alexandre. 2007. Desenvolvimento em Camadas.
http://www.microsoft.com/brasil/msdn/tecnologias/arquitetura/Layers_Developing.mspx

Filho, Fernando Gebara. 2007. Soluç�o para um sistema largamente distribu�do.
http://www.microsoft.com/brasil/msdn/tecnologias/Arquitetura/Solucao_Sistema_Distribuido.mspx

Kalidindi, Ravi e Kalidindi, Rohini. 2007. Best Practices to Improve Performance Using Patterns in J2EE. http://www.pre�cisejava.com/javaperf/j2ee/Patterns.htm

Neward, Ted. 2006. Arquitetura Pragm�tica: Camadas.
http://www.microsoft.com/brasil/msdn/tecnologias/arquitetura/NPALayering.mspx

Panchal, Nimesh. 2003. Implementing MVC Design Pattern in .NET.
http://www.c-sharpcorner.com/uploadfile/napanchal/mvcdesign12052005035152am/mvcdesign.aspx

Macoratti, Jos� Carlos. 2007. Padr�es de Projeto: O modelo MVC � Model View Controller.
http://www.macoratti.net/vbn_mvc.htm

Artigo .net Magazine 65 - Construa uma Aplica��o 100% OO � Parte 5

Uma visão prática e realista do desenvolvimento de sistemas orientados a objetos.

Atenç�o: esse artigo tem uma palestra complementar. Clique e assista!

Artigos relacionados